@echo off
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Steps to overcome HP mPCIE whitelisting
::
:: This batch file creates a PCI Extended Configuration space snapshot with
:: a valid whitelist compatible wifi card. The snapshot then enables the mPCIe
:: port so a non-whitelisted wifi card can work, or my external HD4670 
:: mPCIe-to-pcie adapter. This works with the 2510P, but in my brief testing
:: with a Pavilion DV2000 was not successful.
::
:: NOTE: ensure you put cellophane tape over the wifi card's pin20 otherwise
:: the wifi card will be detected but radio won't come on.  Pin20 is some sort
:: of hardware control that turns the radio off, which the bios does when
::
:: This script has two modes of operation. It's initial run will create a 1MB snapshot
:: file. It's subsequent runs will use the snapshot file to undo HP whitelisting.
::
:: USER DEFINED PARAMETERS
::
:: * MCFG - your PCI Extended Configuration Memory Space location. R-W
::          Everything Win software can tell you. Refer to MCFG tab in ACPI/DSDT.
:: * size - found anything less than 1MB did not work on the 2510P.
:: * FNAME - a unique filename indentifier for your snapshot file
::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: HP 2510P parameters
set MCFG=0xF8000000
set size=0x100000
set FNAME=2510pcix

:: DV2000 parameters
:: set MCFG=0xE0500000
:: set size=0x100000
:: set FNAME=dv2pcix

if EXIST %FNAME%.exe goto UNDO_WHITELIST
echo *************************************************************************
echo [ whitelst.bat ] Entering snapshot mode
echo.
echo WARNING: No %FNAME%.exe file found.
echo.
echo Ensure system was booted with whitelist compatible mPCIe wifi card installed.
echo Press any key to taking PCI Memory Configuration space snapshot now...
pause > nul
echo Creating RAM disk for dump space...
xmsdsk 4096 E: /y
echo Saving E:\%FNAME%.dmp with MCFG@%MCFG% size=%size% bytes.
pt MEM readtofile 1 %MCFG% %size% E:\%FNAME%.dmp
echo Saving as SFX file to save space...
arj a -je1 %FNAME%.exe E:\%FNAME%.dmp
echo Please reboot without whitelist compatible wifi card and run whitelst.bat
echo to see if this overcomes your whitelisting.
echo *************************************************************************
:loop
goto loop

:UNDO_WHITELIST
echo [ whitelst.bat ] Undoing mPCIe whitelisting
echo Using 4MB ramdisk to speed up the process
xmsdsk 4096 E: /y > nul
%FNAME%.exe E: > nul
pt MEM writefromfile 1 %MCFG% E:\%FNAME%.DMP
if errorlevel 0 goto DONE
echo [ whitelst.bat ] Unexpected ERROR!!
pause 
:DONE
echo [ whitelst.bat ] Completed successfully.